Initializing help system before first use

# Examples

Topics covered in this chapter:

- Calling a REST endpoint on an Xpress Executor component
- Calling a REST endpoint on DMP Manager

## Calling a REST endpoint on an Xpress Executor component

This example demonstrates fetching the list of executions from an Xpress Executor component in the same solution.

    model countexecutions
      uses 'dmp','mmxml'

      declarations
        xecomp: dmpresource
        httpstatus: integer
        doc: xmldoc
        nodes: list of integer
      end-declarations

      ! Initialize dmpresource
      dmpinitcomp(xecomp, 'Xpress Executor')
      if xecomp.status<>DMP_OK then
        writeln('ERROR finding Xpress Executor component: ',xecomp.lasterror)
        exit(1)
      end-if

      ! Make request
      httpstatus := dmphttpget(xecomp, '/rest/runtime/execution', 'executions.json')
      if httpstatus<>200 then
        if xecomp.status<>DMP_OK then
          writeln('ERROR authorizing Xpress Executor component: ',xecomp.lasterror)
        else
          writeln('ERROR returned by Xpress Executor component: ',httpstatus)
        end-if
        exit(1)
      end-if

      ! Use mmxml to parse response
      jsonload(doc,'executions.json')
      getnodes(doc,'/jsv/jsv',nodes)
      writeln('Executions found: ',nodes.size)

    end-model

The use of Xpress Executor webservices here is for example purposes only; we recommend using the executor module to interact with Xpress Executor components.

## Calling a REST endpoint on DMP Manager

This example demonstrates calling the REST endpoint on DMP Manager to commit a solution revision.

    model commitsolution
      uses 'dmp','mmsystem'

      declarations
        xecomp: dmpresource
        httpstatus: integer
        public REQUEST_BODY='{"label":"commitSolutionTest","comment":"dmp module example"}'
      end-declarations

      ! Initialize dmpresource
      dmpinitmanager(xecomp)
      if xecomp.status<>DMP_OK then
        writeln('ERROR finding DMP Manager: ',xecomp.lasterror)
        exit(1)
      end-if

      ! Make request
      httpstatus := dmphttppost(xecomp, '/rest/dmp/runtime/solutions/'+getdmpsolid+'/revisions?async=false',
        'text:REQUEST_BODY', 'response.dat')
      if httpstatus<>200 then
        if xecomp.status<>DMP_OK then
          writeln('ERROR making DMP Manager request: ',xecomp.lasterror)
        else
          writeln('ERROR returned by DMP Manager request: ',httpstatus)
        end-if
        exit(1)
      end-if

      writeln('Committed new solution revision')

    end-model

Parent Topic Mosel DMP Module

© 2001-2026 Fair Isaac Corporation. All rights reserved. This documentation is the property of Fair Isaac Corporation (“FICO”). Receipt or possession of this documentation does not convey rights to disclose, reproduce, make derivative works, use, or allow others to use it except solely for internal evaluation purposes to determine whether to purchase a license to the software described in this documentation, or as otherwise set forth in a written software license agreement between you and FICO (or a FICO affiliate). Use of this documentation and the software described in it must conform strictly to the foregoing permitted uses, and no other use is permitted.