(!******************************************************
   Mosel Example Problems
   ======================

   file foliocsv.mos
   `````````````````
   Modeling a small LP problem 
   to perform portfolio optimization.
   -- Parameters, data input from CSV, 
      result output to CSV format --
   
  (c) 2012 Fair Isaac Corporation
      author: S.Heipcke, Nov. 2012
*******************************************************!)

model "Portfolio optimization with LP (CSV)"
 uses "mmxprs", "mmsheet"

 parameters
  DATAFILE = "folio.csv"             ! CSV spreadsheet with problem data
  DBDATA = "[C6:F15]"                ! Spreadsheet range with problem data
  DBSOL = "[H6:I6]"                  ! Range for solution data 
  
  MAXRISK = 1/3                      ! Max. investment into high-risk values
  MAXVAL = 0.3                       ! Max. investment per share
  MINAM = 0.5                        ! Min. investment into N.-American values
 end-parameters

 declarations
  SHARES: set of string              ! Set of shares
  RET: array(SHARES) of real         ! Estimated return in investment
  RISK: array(SHARES) of boolean     ! List of high-risk values among shares
  NA: array(SHARES) of boolean       ! List of shares issued in N.-America
 end-declarations

! Data input from spreadsheet  
 initializations from "mmsheet.csv:" + DATAFILE
   [RET,RISK,NA] as DBDATA
 end-initializations

 declarations
  frac: array(SHARES) of mpvar       ! Fraction of capital used per share
 end-declarations

! Objective: total return
 Return:= sum(s in SHARES) RET(s)*frac(s) 

! Limit the percentage of high-risk values
 sum(s in SHARES | RISK(s)) frac(s) <= MAXRISK

! Minimum amount of North-American values
 sum(s in SHARES | NA(s)) frac(s) >= MINAM

! Spend all the capital
 sum(s in SHARES) frac(s) = 1
 
! Upper bounds on the investment per share
 forall(s in SHARES) frac(s) <= MAXVAL

! Solve the problem
 maximize(Return)

! Solution printing
 writeln("Total return: ", getobjval)
 forall(s in SHARES) 
  writeln(strfmt(s,-12), ": \t", strfmt(getsol(frac(s))*100,5,2), "%")

! Solution output to spreadsheet
 declarations
  Solfrac: array(SHARES) of real      ! Solution values
 end-declarations

 forall(s in SHARES) Solfrac(s):= getsol(frac(s))*100
 
 initializations to "mmsheet.csv:" + DATAFILE
   Solfrac as "grow;"+DBSOL
 end-initializations

end-model